Patch Ideas... Part 2.

[xljem]

;*** Counter for SMS ***
;Firmware : 6688iV5508
;Author：coollang[SPGC]
;Release：2004-02-25 -v1
;Making a counter for SMS sent and received. Change the "help" in the menu of SMS to become the message menu, the left softkey is to set the counter to zero.

0x33A54E: 32BEF4 501EBF
0x33A5C2: AF014103 DF04DF04
0x3C917C: DADC5CD2 DABF801F
0x340C86: DADDDA80 DABF941F
0x340CD6: DADDDA80 DABF941F

0x1F1E50: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 889088808870886026F04000F0C066FC
0x1F1E60: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF FF3FF2FD02FEE6FE321FE6FFFC02DAC7
0x1F1E70: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 1685E0A8D7400E00F2F6323AF0C6F0D0
0x1F1E80: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 66FDFF3FF2FE02FE00D8DAC71E89F0C4
0x1F1E90: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF F0D5DAC736850084E1D2F0C800C0B92C
0x1F1EA0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 0881F0C066FCFF3FF2FD02FE00C8E6FE
0x1F1EB0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 3D1FE6FFFC02DAC716850886D7400E00
0x1F1EC0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF F2F6343AF0C6F0D066FDFF3FF2FE02FE
0x1F1ED0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 00D8DAC71E89F0C4F0D5DAC736850084
0x1F1EE0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF E1020080B928E6FC8B13F0D066FDFF3F
0x1F1EF0: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF F2FE02FEE00FDAE4CEA7E6FC601FE6FD
0x1F1F00: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF FC02E6FE5C1FE6FFFC02DADDE48F06F0
0x1F1F10: FFFFFFFFFFFFFFFFFFFFFFFF 40009860987098809890DB00
0x1F1F1C: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 46FE3800EA30301FD7500E00F68E323A
0x1F1F2C: FFFFFFFFFFFF F68E343ADB00
0x1F1F32: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 52656369657665643A200053656E743A
0x1F1F42: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 200038005200060252005200FEFF5200
0x1F1F52: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 5200FEFF2500520074028B13FF7F0040
0x1F1F62: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 0000220000000000DF04000000001C1F
0x1F1F72: FFFFFFFFFFFFFFFFFFFFFFFFFFFF BF0000000000441FFC0200000000

0x1F1F80: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF E6000E00F2F4323A0841F6F4323ADADC
0x1F1F90: FFFFFFFF 5CD2DB00
0x1F1F94: FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF E6000E00F2F4343A0841F6F4343ADADD
0x1F1FA4: FFFFFFFF DA80DB00


************************************************** *

$Segmented
$Mod167

;Memory Function
memchr EQU 0xC78360 ;Finds characters in a buffer. R12 = Offset R13 = Page R14 = Char R15 = Size
memcmp EQU 0xC78388 ;[R0] = Size.
memcpy EQU 0xC783DC ;[r0] = size r12 = Dstoff r13 = Dstpag r14 = Srcoff r15 = Srcpag
memset EQU 0xC78416 ;R13:R12 = pDst R14 = char r15 = size

;String Function
strcat EQU 0xC784A6 ;Append a string. r12 = Dstoff r13 = Dstpag r14 = Srcoff r15 = Srcpag
strchr EQU 0xC784CC ;Find a character in a string. R12 = Offset R13 = Page R14 = Char
strrchr EQU 0xC785CC ;Scan a string for the last occurrence of a character.
strcmp EQU 0xC784EE ;Compare strings. r12 = Dstoff r13 = Dstpag r14 = Srcoff r15 = Srcpag
strncmp EQU 0xC78578 ;Compare strings. [R0] = Size
strcpy EQU 0xC78516 ;Copy a string. r12 = Dstoff r13 = Dstpag r14 = Srcoff r15 = Srcpag
strncpy EQU 0xC7859E ;R13:R12 = DST R15:R14 = SRC [R0] = size
strcspn EQU 0xC785F0 ;Find a substring in a string.r12 = Setoff r13 = Setpag r14 = SubSrcoff r15 = SubSrcpag
strset EQU 0xC78416 ;Set characters of a string to a character.R12 = Offset R13 = Page R14 = Char R15 = Size
strlen EQU 0xC78536 ;R12 = Offset R13 = Page R4 = Length

;String format
sprintf EQU 0xA4D282 ;R13:R12 = pDst R15:R14 = Format [r0...]...
WordToDigString_LE_6 EQU 0xC7891E

;AT Function
SendATCommand EQU 0xCC9DCC ;Send reply string.
GetATCommandLine EQU 0xCD6B68
StoreStringR13R12toSendLater EQU 0xCDB04C

;MenuFunction
CreateMenu EQU 0xF5BB52
SetMenu EQU 0xF648C2
GetSelectMenu EQU 0xF64A28
UpdateMenu EQU 0xF6302C

ShowMessageDlg EQU 0xDD8FE4

StoreTextAsStringId EQU 0xE4A7CE ;void StoreTestAsStringId(int ID, char far *String, int unknown = 0)
ClearStringID EQU 0xE4A990 ;void ClearStringID(int ID, int unknown = 0)


;Address for Patch Data
BattleHistoryAddress EQU 0x03BA32
Flash_Address EQU 0x800000
MAIN_Address EQU 0xBF1E20

Patch Section Code Word At MAIN_Address ; Start Patch at Patch_Address
main proc far ; start main of patch

mov [-r0], r9
mov [-r0], r8
mov [-r0], r7
mov [-r0], r6
sub r0, #40h
mov r12, r0
and r12, #3FFFh
mov r13, DPP1
mov r14, #pof(strRecieved)
mov r15, #pag(strRecieved)
calls seg(strcpy),sof(strcpy)
mov r8, #10

extp #pag(BattleHistoryAddress),#1
mov R6, pof(BattleHistoryAddress)
mov r12, R6
mov r13, r0
and r13, #3FFFh
mov r14, DPP1
add r13, r8
calls seg(WordToDigString_LE_6), sof(WordToDigString_LE_6)
mov r12, r4
mov r13, r5
calls seg(strlen), sof(strlen)
add r8, r4

movb rl1, #0Dh
mov r12, r8
add r12, r0
movb [r12], rl1
add r8, #1

mov r12, r0
and r12, #3FFFh
mov r13, DPP1
add r12, r8
mov r14, #pof(strSent)
mov r15, #pag(strSent)
calls seg(strcpy),sof(strcpy)
add r8, #6

extp #pag(BattleHistoryAddress+2),#1
mov R6, pof(BattleHistoryAddress+2)
mov r12, R6
mov r13, r0
and r13, #3FFFh
mov r14, DPP1
add r13, r8
calls seg(WordToDigString_LE_6), sof(WordToDigString_LE_6)
mov r12, r4
mov r13, r5
calls seg(strlen), sof(strlen)
add r8, r4

movb rl1, #0
add r8, r0
movb [r8], rl1
mov r12, #138Bh
mov r13, r0
and r13, #3FFFh
mov r14, DPP1
mov r15, #0
calls 0E4h, StoreTextAsStringId
mov r12, #pof(WndClass)
mov r13, #pag(WndClass)
mov r14, #pof(TextList)
mov r15, #pag(TextList)
calls 0DDh, ShowMessageDlg

add r0, #040h ; '?
mov r6, [r0+]
mov r7, [r0+]
mov r8, [r0+]
mov r9, [r0+]
rets

main endp

NewOnSelect proc far ; start main of patch
cmp R14, #38h
jmpa cc_NZ, EndPro
extp #pag(BattleHistoryAddress),#2
mov pof(BattleHistoryAddress), ZEROS
mov pof(BattleHistoryAddress+2), ZEROS
EndPro:
rets
NewOnSelect endp



strRecieved:
db 'Recieved: ', 0
strSent:
db 'Sent: ', 0

SKeyList:
dw 38h
dw 52h
dw 206h
dw 52h
dw 52h
dw 0FFFEh
dw 52h
dw 52h
dw 0FFFEh
dw 25h
dw 52h
dw 274h

TextList:
; dw 56Dh
dw 138Bh
dw 7FFFh
WndClass:
dw 4000h ; Flag1
dw 0 ; Flag2
dw 22h ; Flag3
dw 0 ; TimeToKeep
dw 0 ; unknown
dw 4DFh ; DialogTitle
dw 0 ; Offset
dw 0 ; Page
dw sof(NewOnSelect) ; HandleOffset
dw seg(NewOnSelect) ; HandlePage
dw 0 ; Offset1
dw 0 ; Page1
dw pof(SKeyList) ; ButtondefOffset
dw pag(SKeyList) ; ButtondefPage
dw 0 ; field_1C
dw 0 ; field_1E

InSMS proc far
mov DPP0, #pag(BattleHistoryAddress)
mov r4, pof(BattleHistoryAddress)
add r4, #1
mov pof(BattleHistoryAddress), R4
calls 0DCh, 0D25Ch
rets
InSMS endp
OutSMS proc far
mov DPP0, #pag(BattleHistoryAddress)
mov r4, pof(BattleHistoryAddress+2)
add r4, #1
mov pof(BattleHistoryAddress+2), R4
calls 0DDh, 080DAh
rets
OutSMS endp

Patch EndS
END



The following link is the ida file for 6688i:

http://www.konca.com/mobile/file/konca_6688_idb.rar

[xljem]

Originally Posted by lalo.lerry

Uhm, very interesting.
There is also for S45i?
Could you post same more 6618i chinese patches?
10Q

There is not for S45i, because I can only write the simple patch. Maybe another patcher will convert this patch into 3618 in recent days. If so, I will post it here.

[MacKam]

@xljem

Could You make a list of 6688i patches. I mean only like: *** Counter for SMS *** ??

Another ideas:

# *** Supernet for SL45 v0.31 beta *** when keypad is locked. Add option to Application menu like in SOL3 e.g. Supernet-L.

# FullSecean "radar" animation.


# *** CLST2. Call List via GREEN button aka Extended Call List v2 *** and
*** Toggling between SIM-Location and Addressbook when entering SMS Recipient No. ***

Mix this patches for SMS sendind to I mean: ***Toggling between SIM-Location, Addressbook and Dialled Calls when entering SMS Recipient No.by Red Button or Left Arrow.

[xljem]

Show Number while dialling and vibra when the other side picks up the phone

;Firmware : 6688iV5508
;Author: MrJewes

************************************************** ********
$Segmented
$Mod167

;Some Function
DrawImagebyIndex EQU 0xB3DF04
GetVibraStatByProfile EQU 0xB5D570
pSendMessage EQU 0xB4724C

;SOme Address
PatchBegin EQU 0x1F2000

patch section code word AT PatchBegin

main proc far
extp r15, #1
mov r14, [r14]
cmp r14,#0C6h
jmp cc_z,begin_vibra
cmp r14,#0c2h
jmp cc_z,Numberinphone
cmp r14,#0c3h
jmp cc_z,Numberinphone
cmp r14,#0CAH
jmp cc_c,clear
cmp r14,#0CDh
jmp cc_UGT,clear
;whether has the number in phonebook,if so, show the number
extp #0Ch,#1
movb rl4,2b84h
cmpb rl4,#0
jmp cc_z,Numberinphone
callr showdialnumber
Numberinphone:
mov r4,#1
jmp cc_uc,out

begin_vibra:
extp #0ch,#1
mov r4,23c6h
cmp r4,#0
jmp cc_z,out
mov [-r0],r12
mov [-r0],r13
mov [-r0],r14
mov [-r0],r15
calls seg(Vibra+0xA00000),SOF(Vibra+0xA00000)
mov r15,[r0+]
mov r14,[r0+]
mov r13,[r0+]
mov r12,[r0+]
clear: mov r4,#0
out:
extp #0ch,#1
mov 23c6h,r4
rets
main endp
ClearVibraFlag proc far
mov r12,r9
mov r13,r6
MOV R4,#0
extp #0ch,#1
mov 23c6h,r4
RETS
ClearVibraFlag endp


showdialnumber proc near
mov [-r0], r1
mov [-r0], r4
mov [-r0], r12
mov [-r0], r13
mov [-r0], r14
mov [-r0], r15
mov r14,#23c8h
mov r15,#2b85h

loop: extp #0ch,#1
movb rl1,[r15+]
movb rh1,rl1

cmpb rl1,#0FFh
jmp cc_z,wordend ;If it is even

cmpb rl1,#0
jmp cc_z,doublezero

addb rl1,#0F0H ;If it is odd
cmpb rl1,#0F0h
jmp cc_z,wordnearend
mov rl1,rh1
mov rh1,#0
shl r1,#4
mov r4,r1
and r4,#0FFh
shr r4,#4
mov rl1,rl4;r1=0801
callr save
jmp cc_uc,loop
wordnearend:
movb rl1,rh1
andb rl1,#0fh
movb rh1,#0FFh
callr save
jmp cc_uc,begintoshow

wordend:
movb rl1,#0Fh
extp #0ch,#1
movb [r14],rl1
jmp cc_uc,begintoshow
doublezero:
mov r1,#0
callr save
jmp cc_uc,loop
;begin to show number！
begintoshow:
callr getlen
cmp r4,#0bh ;whether the number is more than 11
jmp cc_ULT,small
sub r4,#0bh
mov r12,#11h
jmp cc_uc,start

small: mov r12,r4 ;automatically move to center
shl r12,#2
shl r4,#1
add r12,r4
neg r12
add r12,#100
shr r12,#1
mov r4,#0

start:
add r4,#23c8H
loop2:

extp #0ch,#1
movb rl1,[r4+]
cmpb rl1,#0Fh
jmp cc_z,showover
movbz r14,rl1
callr showpic
jmp cc_uc,loop2

showover:
mov r15, [r0+]
mov r14, [r0+]
mov r13, [r0+]
mov r12, [r0+]
mov r4, [r0+]
mov r1, [r0+]
ret
showdialnumber endp
;put the number in r1 into buffer
save proc near
extp #0ch,#1
mov [r14],r1
add r14,#2
ret
save endp

getlen proc near
mov r14,#23c8h
mov r4,#0
loop1:
extp #0ch,#1
movb rl1,[r14+]
cmpb rl1,#0FFH
jmp cc_z,exitwith0
cmpb rl1,#0FH
jmp cc_z,endofnumber
add r4,#1
jmp cc_uc,loop1
exitwith0:
mov r4,#0
endofnumber:
ret
getlen endp

showpic proc near

mov [-r0],r4
mov [-r0],r12
add r14,#20dh
mov r13,#0Ah
calls seg(DrawImagebyIndex),sof(DrawImagebyIndex)
mov r12,[r0+]
mov r4,[r0+]
add r12,#6
ret
showpic endp

Vibra proc far
calls seg(GetVibraStatByProfile),sof(GetVibraStatByProfi le)
cmp r4,#0
jmp cc_nz,V_out
mov r12, #1
mov [-r0], r12
mov r13, #2
mov [-r0], r13
mov r12, #34C0h
mov r13, #0Eh
mov r14, #2
mov r15, #2FH
calls seg(pSendMessage), sof(pSendMessage)
add r0, #4
V_out:
rets
Vibra endp
patch ends
End

[xljem]

hang up the phone timely (automatically)

;Firmware : 6688iV5508
;Author: RainMoon

******************************************

$Segmented
$Mod167

; Menu Function
TipMenu EQU 0E60508h

;立即数
HungUp EQU 3AH ;hang up（3A/58 seconds）
STR_ON EQU 6D6H ;activate
STR_OFF EQU 6D7H ;close

;Address for Patch Data
Patch_Address EQU 027E0F0h ;Free Space in Flash (CHANGE THIS)
PlayKey_Address EQU 027E158h ;Free Space in Flash (CHANGE THIS)

Patch Section Code Word At Patch_address ; Start Patch at Patch_Address

;-----FOR 6688v55-------RainMoon----------------------------------;
main proc far ; start main of patch
;// At Smart Time
calls 0A0h,02FDAh
calls seg(ReadSOF),sof(ReadSOF)
cmp r12,#1
jmpr cc_NZ,loc_Ori
;// r4 MOD r12 = HungUp Time
mov r12,#3Ch
mov MDL,r4
div r12
mov r12,MDH
cmp r12,#HungUP
jmpr cc_NZ,loc_Ori
;// HungUp
calls 0D5h,0ACB4h
;calls 0B3h,062A8h ;// Test Func OpenLight
mov r12,#0 ;// SET Zero after run
calls seg(WriteSOF),sof(WriteSOF)
loc_Ori:
calls 0A0h,02FDAh
rets
main endp

ReadSOF proc far
mov DPP0,#34h
mov r12,022A2h
rets
ReadSOF endp

WriteSOF proc far
mov DPP0,#34h
mov 022A2h,r12
rets
WriteSOF endp

SmartONOFF proc far ; start main of patch
mov r13,#STR_OFF
calls seg(ReadSOF),sof(ReadSOF)
cmp r12,#1
jmpr cc_NZ,loc_CaseZero
mov r12,#0
jmpr cc_UC,loc_ToWri
loc_CaseZero:
mov r12,#1
loc_ToWri:
calls seg(WriteSOF),sof(WriteSOF)
sub r13,r12
mov r12,#1
calls seg(TipMenu),sof(TipMenu)
rets
SmartONOFF endp

Patch EndS

Patch2 Section Code Word At PlayKey_address ; Start Patch at Patch_Address
PlayKey proc far
cmp r12,#3Eh
jmpr cc_Z,loc_OKey
cmp r12,#62h
jmpr cc_Z,loc_OKey
jmps 0D5h,0ADB2h
loc_OKey:
jmps 0D5h,0ADAEh
PlayKey endp
Patch2 EndS

END

[xljem]

The explaination of source code for some patches is written in Chinese, it is difficulty for me to translate.
And, there are some small usefull patches, I will post them here asap.

[MacKam]

@xljem

The explaination of source code for some patches is written in Chinese, it is difficulty for me to translate.
And, there are some small usefull patches, I will post them here asap.

thx. for doing it!

regards

~~~~~~~~~~~~~

Any progress with adapting Call Logging patch for SLIK ?

[genetic1]

Hello,

i'm newbie and i found many usefull patches here in this forum.

But i missed one patch...for menu selection standard cursor position...(SME45i)

If i moved to menu (with right softkey) the standard cursor position is "Special" - for me it is not very usefull!!!

I'm sure, that's possible to change the standard cursor position but i don't know how???

Can anybody help me?

My favourite cursor position is "setup"!

Thanks for a little help...

genetic1

[MacKam]

** Add question: Do you want clear SMS Counter? Yes/No when we try press "Clear" to *** SCI. SMS Counter Info ***

*** In Appointments change "OK" button to "Delete" for quick clean Appointments.
Like in picture: http://mackam.fm.interia.pl/tmp/delete.gif

[deschek]

*** Double press Red Button to unblock keys *** I hope it`s understanble, I mean that would be graet to unblock keys with double press red button instead of long press #.

[koper]

Phone conversation with mp3's in background, hearable for both sides od conversation

[MacKam]

# Do not count SMS (Received, Sent) to/from operator like from numbers: 2000, 1000, 2626, 12345. Count only SMS from numbers like +48123456789 or 0123456789 or 123456789 I mean numbers > than 5 counts. In *** SCI. SMS Counter Info ***

[cyperghost]

..........you mean status reports?

[MacKam]

..........you mean status reports?

No. I mean add some SMS counter "filter" from and to some numbers. Because I can for free send SMS to my operator (to check my acount, etc.) So I don't need count them.

But "status reports" it's good idea too.

[MacKam]

One more about "SCI. SMS Counter Info" it is possible to write this information+date into a *.txt file to MMC. Then we can make some SMS statistic in e.g Exel. Somethink like Call loggin.