How to make a patch for SL45.

[nguyentan1980]

Please help me. I cut and paste patchs for SL45, 2 months recently. I want to make own patch.
Please, tell me how can I do it. Let show me the tool and document about this.

[Froster]

Well you can read the topic about falshing and technical discusion thread and gain some information in there. Of course it is not all. You can see RizaPN's site and there download some useful tools -> SFE and other. If you are interested in graphical patches those are made a lot easier - just download SPC2 and have fun

[GoLL@B]

Originally Posted by Froster

just download SPC2 and have fun

Or newer version - SPC3

[nguyentan1980]

Please give me the link for SPC3.
I see a fw5601.rar file on Mamaich home page. Description of this file is "Decompiled SL45i firmware with some comments". When I extract it, I have an "output.idb" file. Please tell me How to open this file.

[lalo.lerry]

with IDA Pro version

[DeadManS]

for exampole if you whant see my miniGPS patch list

ReadEEPROM              EQU 0C22F3Eh
WriteEEPROM             EQU 0C22F92h    
Drawimage		EQU 0C122ECh 
IsCallInProgress	EQU 0CCC64Ch
IsAtFullService		EQU 0A24c18h
longtohexstr		EQU 0C78032h
strstr			EQU 0C785F0h
drawstring		EQU 0D6A358h
FileOpen 		EQU 0DFA73Eh		;r13:r12 = pointer to ASCIIZ filename
						;r4 = Open result, if success r4=fileHandle, if failed, r4=FFFF

FileRead 		EQU 0DFABAEh		;r12=fileHandle r15=size r14:r13 = pointer to buffer
FileClose 		EQU 0DFC570h		;r12=fileHandle
LoadHelper		EQU 0E47FF0h		;r5:r4 - pointer to afterloading func
memset			EQU 0C78416h		;Fill memory r13:r12, size r15 whith r14 code
FillRect		EQU 0C0E5D0h		;R12-Color (1-black, 0-white) (on stack) r12-X r13-Y r14-width r15 -height 
CI			EQU 039D86h
buff			EQU 080000h
stringbuff		EQU 080002h
cellnamebuff		EQU stringbuff+6
filebuff		EQU cellnamebuff+20
b_flag			EQU 0D3E1Bh
BlockSize		EQU 1024





		mov	[-r0],r12
		mov	[-r0],r4
		mov	[-r0],r5
		mov	[-r0],r6
;---------------Load CellID and comprare with Saed Cell ID----------------
		extp	#pag(b_flag),#1
		movb	rl4,pof(b_flag)
		cmpb	rl4,#0
		jmpa	cc_z,endprog

		extp	#pag(ci),#1
		mov	r4,pof(ci)
		ror	r4,#8
		extp	#pag(buff),#1
		mov	r5,pof(buff)
		cmp	r4,r5
		jmpr	cc_z,nochange
;---------------Saving CellID if Cell is change---------
		extp	#pag(buff),#1
		mov	pof(buff),r4
;---------------Loading CellID name from EEPROM--------
		mov     r12, #0
		mov     [-r0], r12
		mov     [-r0], r12
		mov     [-r0], r12
		mov     r12,#BlockSize
		mov     [-r0], r12
		mov     r12, #5169
		mov     r13, #pof(filebuff)
		mov     r14, #pag(filebuff)
		mov     r15, #0
		calls   seg(ReadEEPROM),sof(ReadEEPROM)
		add	r0,#8

;---------------Converting CellID from HEX to string----------
		
		mov	r4,#0
		mov	r12,#2
		mov	[r0],r12
		mov	r12,#pof(stringbuff)
		mov	r13,#pag(stringbuff)
		extp	r13,#1
		movb	[r12+#4],rl4		;end of string identify
		mov	r14,#pof(buff)
		mov	r15,#pag(buff)
		calls	seg(longtohexstr),sof(longtohexstr)
		mov	r4,#0
		extp	#pag(stringbuff),#1
		mov	pof(stringbuff)+4,r4
;---------------Finding CellID in CellID Namelist
		mov	r12,#pag(filebuff)
		mov	r13,#pof(filebuff)
		extp 	#pag(stringbuff),#2
		mov	r4,pof(stringbuff)
		mov	r5,pof(stringbuff)+2
		
find:		extp	r12,#1
		movb	rl6,[r13]
		cmpb	rl6,#0FFh
		jmpr	cc_z,nochange1		;CellName not found
		cmpb	rl4,rl6
		jmpr	cc_nz,nextfind
		extp	r12,#1
		movb	rl6,[r13+#1]
		cmpb	rh4,rl6
		jmpr	cc_nz,nextfind
		extp	r12,#1
		movb	rl6,[r13+#2]
		cmpb	rl5,rl6
		jmpr	cc_nz,nextfind
		extp	r12,#1
		movb	rl6,[r13+#3]
		cmpb	rh5,rl6
		jmpr	cc_nz,nextfind
		jmpr	cc_uc,addrfound
nextfind:	add	r13,#1
		jmpr	cc_uc,find		
;---------------Copy CellID name from CellID List to buffer		
	
addrfound:	add	r13,#5
		mov	r14,#pof(stringbuff)
CopyLoop:	extp	r12,#1
		movb	rl6,[r13]
		cmpb	rl6,#0Dh			; End CellName?
		jmpr	cc_z,EndCopyLoop
		extp	#pag(stringbuff),#1
		movb	[r14],rl6
		add	r13,#1
		add	r14,#1
		jmpr	cc_uc,CopyLoop
EndCopyLoop:	mov	r4,#0
		extp	#pag(stringbuff),#1
		movb	[r14],rl4		;make end of string identify
		
;---------------some NOP's for other programs
nochange1:	nop
		nop
		nop	
		nop
		nop
		nop

	
;---------------Printing CellID Name on main screen

NoChange:       ;---------------Erase old string from screen----------------
		mov	r12,#0
		mov	[-r0],r12
		extp	#pag(coord),#2
		mov	r15,pof(coord)
		mov	r13,pof(coord)+2
		mov	r14,#101
		mov	r12,#0
		calls	seg(FillRect),sof(FillRect)
		add	r0,#2

		mov	r14,#pof(stringbuff)
		mov	r15,#pag(stringbuff)
		mov	r4,#08			;font style
		mov	[-r0],r4
		mov	[-r0],r15
		mov	[-r0],r14
		extp	#pag(coord),#2
		mov	r15,pof(coord)
		mov	r13,pof(coord)+2
		mov	r14,#101
		mov	r12,#0
		calls	seg(drawstring),sof(drawstring)
		add	r0,#6



		
endprog:	mov	r6,[r0+]
		mov	r5,[r0+]
		mov	r4,[r0+]
		mov	r12,[r0+]
		mov	[-r0],r9
		mov	[-r0],r8
		rets

saveEEPROM:	mov	[-r0],r12
;---------------Filling FileBuffer FF byte------------------		
		mov	r13,#pag(filebuff)
		mov	r12,#pof(filebuff)
		mov	r15,#BlockSize+2
		mov	r14,#0FFh
		calls	seg(memset),sof(memset)
;---------------Load CellID list from MMC--------------
		mov	r13,#pag(filename)
		mov	r12,#pof(filename)
		calls	seg(FileOpen),sof(FileOpen)
		cmp	r4,#0FFFFh
		jmpr	cc_z,endload
		mov	r12,r4
		mov	[-r0],r12
		mov	r14,#pag(filebuff)
		mov	r13,#pof(filebuff)
		mov	r15,#BlockSize
		calls	seg(fileread),sof(fileread)
		mov	r12,[r0+]
		calls	seg(fileclose),sof(fileclose)
;---------------Saving CellIDlistto EEPROM-------------	
		mov     r12, #0
		mov     [-r0], r12
		mov     [-r0], r12
		mov     [-r0], r12
		mov     r12,#BlockSize
		mov     [-r0], r12
		mov     r12, #5169
		mov     r13, #pof(filebuff)
		mov     r14, #pag(filebuff)
		mov     r15, #0
		calls   seg(WriteEEPROM),sof(WriteEEPROM)
	       	add     r0, #8
	
endload:	mov	r12,[r0+]
		and	r12,#3FFFh
 		rets

filename:	db	'a:\ci.txt',0	
coord:		db	09,00,07,00

[GoLL@B]

I don`t remember where I find it. I placed it on my server. You can download it from here: http://www.gollab.republika.pl/SPC3.rar .

I have polish language so you must change it : Ustawienia/Language

[lalo.lerry]

Originally Posted by GoLL@B

I don`t remember where I find it. I placed it on my server. You can download it from here: http://www.gollab.republika.pl/SPC3.rar .

Developer site (patchmaster ACiD) is at www.GSM-dev.com